FUTURE ATM

@計算收支平衡
您可以在 Excel 中建立支票登記簿來記錄金錢交易。作為試算表的一部分，您可以建立公式來計算收支平衡。在本範例中，假設儲存格 F6 中含有上一次的餘額，儲存格 D7 中含有第一筆交易的存款總數，而儲存格 E7 中含有任意的現金收入額。

若要計算第一筆交易的餘額，請在儲存格 F7 中輸入下面的公式：

=SUM(F6,D7,- E7)

如果又輸入了一些新的交易，那麼可將此公式複製到與每個新的交易相對應到的儲存格中。

@合併姓名
您可以利用公式將儲存在一欄中的姓和儲存在另一欄中的名連接起來。在範例中，假定儲存格 D5 包含名，儲存格 E5 包含姓。

若要以格式 [名 姓] (如 [John Smith] ) 顯示全名：

=D5&" "&E5

若要以格式 [姓,名] (如 [Smith,John] ) 顯示全名：

=E5&", "&D5

@合併日期與文字
若要將兩個值合併 (或連接) 為一個連續的文字值，請使用 & (與) 文字運算子。若要將儲存在儲存格中的數字、日期或時間值與字串相連，請使用 TEXT 工作表函數。例如，如果儲存格 F5 中含有 [5-Jun-99] 這樣一個日期值，那麼可以使用下面的公式顯示這樣的文字 [陳述日期：5-Jun-99] ：

="陳述時間："&TEXT(F5, "d-mmm-yy")

@按百分比增加
您可以將儲存在儲存格中的數值增加若干個百分點，例如增加百分之五。在本範例中，假定儲存格 F5 中包含一個起始值。

=F5*(1+5%)

如果百分點數值儲存在儲存格中(例如儲存格 F2)：

=F5*(1+$F$2)

對儲存格 F2 的參照是儲存格絕對位址，所以這個公式可以被複製到其它儲存格，而不會改變對 F2 的參照。

@根據單一條件進行總和
您可以根據其他區域中的值，透過使用 SUMIF 工作表函數對區域進行加總。例如，對於區域 B5:B25 中包含數值 [Northwind] 的每個儲存格而言，下面的公式可為區域 F5:F25 中相對應到的儲存格進行加總。

=SUMIF(B5:B25,"Northwind",F5:F25)

@根據多個條件進行總和
請使用下面的公式來對區域 F5:F25 進行加總，其中的區域 B5:B25 中包含 [Northwind] 且 區域 C5:C25 中包含 [Western] 。

=SUM(IF((B5:B25="Northwind")*(C5:C25="Western"),F5:F25))

若要對儲存格區域 F5:F25 的值進行總和 (其中，儲存格區域 B5:B25 中含有 [Northwind] 或 [Terra Firm] )，請使用下面的公式：

=SUM(IF((B5:B25="Northwind")+(B5:B25="Terra Firm"),F5:F25))

@累計某個條件的出現次數
COUNTIF 工作表函數可累計特定數值在儲存格區域中出現的次數。例如，可累計區域 B5:B25 中包含文字 [Northwind] 的儲存格個數。

=COUNTIF(B5:B25,"Northwind")

@累計多個條件的出現次數
在下面的公式中，每當 Excel 在 B5:B25 中找到 [Northwind] 時，它就會檢查同一列中 C 欄 (C5:C25 這一範圍) 上的值是否為 [Western] 。然後 Excel 將會計算包含這兩個條件的列出現的次數。

=SUM(IF(B5:B25="Northwind",IF(C5:C25="Western",1,0)))

這是一個陣列公式，輸入時必須按 CTRL+SHIFT+ENTER 組合鍵。

http://imil.au.edu.tw/~hsichcl/Excel/Unit3/excel3_2_5.htm#xlrefexamplesofcommonformulas_7